#include "Mouse.h"

int DATA_CLOCK    = 6;
int DATA_LATCH    = 7;
int DATA_SERIAL  = 12;

int range = 5;    // output range of X or Y movement; affects movement speed

int buttons[32];
int x = 0;
int y = 0;

void setup(){
  setupPins();
  Mouse.begin();
}

void loop(){
  getControllerData();
  updateMouse();
  delay(1);
}

void setupPins(void){
  // Set DATA_CLOCK normally HIGH
  pinMode(DATA_CLOCK, OUTPUT);
  digitalWrite(DATA_CLOCK, HIGH);
  
  // Set DATA_LATCH normally LOW
  pinMode(DATA_LATCH, OUTPUT);
  digitalWrite(DATA_LATCH, LOW);

  // Set DATA_SERIAL normally HIGH
  pinMode(DATA_SERIAL, OUTPUT);
  digitalWrite(DATA_SERIAL, HIGH);
  pinMode(DATA_SERIAL, INPUT);  
}

void getControllerData(void){
    // Latch for 12us
    digitalWrite(DATA_LATCH, HIGH);
    delayMicroseconds(12);
    digitalWrite(DATA_LATCH, LOW);
    delayMicroseconds(6);
    
    for(int i = 0; i < 32; i++){
        digitalWrite(DATA_CLOCK, LOW);
        delayMicroseconds(6);
        buttons[i] = 1 - digitalRead(DATA_SERIAL);
        digitalWrite(DATA_CLOCK, HIGH);
        delayMicroseconds(6);
    }
    bool output = false;

}

void updateMouse(){
  if (buttons[9] == 1) {
    // if the mouse is not pressed, press it:
    if (!Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.press(MOUSE_LEFT);
    }
  }
  // else the mouse button is not pressed:
  else {
    // if the mouse is pressed, release it:
    if (Mouse.isPressed(MOUSE_LEFT)) {
      Mouse.release(MOUSE_LEFT);
    }
  }

  if (buttons[8] == 1) {
    // if the mouse is not pressed, press it:
    if (!Mouse.isPressed(MOUSE_RIGHT)) {
      Mouse.press(MOUSE_RIGHT);
    }
  }
  // else the mouse button is not pressed:
  else {
    // if the mouse is pressed, release it:
    if (Mouse.isPressed(MOUSE_RIGHT)) {
      Mouse.release(MOUSE_RIGHT);
    }
  }

  //get x\y offset
  x = 0;
  y = 0;
  for (int i = 0; i < 7; i++)
  {
    x *= 2;
    y *= 2;
    x += buttons[17+i];
    y += buttons[25+i];
  }
  
  if (buttons[16]==1){
    x = x *-1;
  }
  if (buttons[24]==1){
    y = y *-1;
  }
  
  if ((x != 0) || (y != 0)) {
    Mouse.move(y*range, x*range, 0);
  }

}